FX

/* 
 * DO NOT ALTER OR REMOVE COPYRIGHT NOTICES OR THIS FILE HEADER
 * Copyright 2009 Sun Microsystems, Inc. All rights reserved. Use is subject to license terms. 
 * 
 * This file is available and licensed under the following license:
 * 
 * Redistribution and use in source and binary forms, with or without 
 * modification, are permitted provided that the following conditions are met:
 *
 *   * Redistributions of source code must retain the above copyright notice, 
 *     this list of conditions and the following disclaimer.
 *
 *   * Redistributions in binary form must reproduce the above copyright notice,
 *     this list of conditions and the following disclaimer in the documentation
 *     and/or other materials provided with the distribution.
 *
 *   * Neither the name of Sun Microsystems nor the names of its contributors 
 *     may be used to endorse or promote products derived from this software 
 *     without specific prior written permission.
 * 
 * THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS "AS IS" AND
 * ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED
 * WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE ARE
 * DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT OWNER OR CONTRIBUTORS BE LIABLE FOR
 * ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES
 * (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES;
 * LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON
 * ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
 * (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF THIS
 * SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
 */
package tweeter.view.list;

import javafx.scene.CustomNode;
import javafx.scene.Group;
import javafx.scene.image.Image;
import javafx.scene.image.ImageView;
import javafx.scene.Node;
import javafx.scene.paint.Color;
import javafx.scene.shape.Line;
import javafx.scene.shape.Rectangle;
import javafx.scene.text.Font;
import javafx.scene.text.Text;
import javafx.scene.text.TextOrigin;
import javafx.scene.input.MouseEvent;
import tweeter.view.ImageButton;
import tweeter.model.Status;
import tweeter.view.list.ListView;
import tweeter.view.TweeterView;

/**
 * View to display Item in Status List
 */

public def height = 72.0;

public class ListItem extends CustomNode { 
    
    public var listView : ListView;
    public var status : Status;
    public var canDelete = false;
    public var onDelete: function(id : String) = null;
    
    var deleteButton : ImageButton = ImageButton {
        translateX: 197
        translateY: 3
        normalImage: TweeterView.theme.deleteImage
        visible: bind canDelete
        onMousePressed: function(e) {
            if(onDelete != null) {
                canDelete = false;
                opacity = 0.5;
                onDelete(status.id);
            }
        }
    };

    var photo = ImageView {
        image: TweeterView.theme.photoImage
        x: 3
        y: 10
        fitWidth: 48
        fitHeight: 48
        preserveRatio: true
    };
    
    var user = Text {
        x: 55
        y: 6
        font: Font { name: "dialog" size: 9 }
        fill: bind Color.web("#{TweeterView.theme.linkColor}")
        content: ""
        wrappingWidth: 148
        textOrigin: TextOrigin.TOP
    };
    
    var text = Text {
        x: 55
        y: 18
        font: Font { name: "dialog" size: 9 }
        fill: bind Color.web("#{TweeterView.theme.textColor}")
        content: ""
        wrappingWidth: 148
        textOrigin: TextOrigin.TOP
    };
    
    var bgRect = Rectangle {
        x: 2
        y: 2
        width: 208
        height: 66
        fill: bind (if(hover) { Color.WHITE } else { Color.TRANSPARENT })
        stroke: bind (if(hover) { Color.web("#{TweeterView.theme.linkColor}") } else { Color.TRANSPARENT })
        strokeWidth: 0.5
        arcWidth: 5
        arcHeight: 5
    }

    var topLine = Line {
        startX: 0
        startY: height - 1
        endX: 213
        endY: height - 1
        stroke: Color.GRAY
    };

    var bottomLine = Line {
        startX: 0
        startY: height
        endX: 213
        endY: height
        stroke: Color.WHITE
    };
    
    override function create():Node {
        Group { 
            content: [ 
                bgRect, photo, user, text, topLine, bottomLine, deleteButton
            ]
        };
    }
    
    override var onMousePressed = function(e : MouseEvent) {
        listView.selectedListItem = this;
    }
    
    public function setStatus(stts : Status) : Void {
        
        if(stts == null) {
            visible = false;
            return;
        }
        
        status = stts;
        
        user.content = trimString("{status.user.name}".trim(), 25);
        text.content = trimString("{status.text}".trim(), 120);
        
        if(status.user.profileImageURL == null) {
            photo.image = TweeterView.theme.photoImage;
        } else {
            photo.image = Image {
                url: status.user.profileImageURL
                backgroundLoading: true
                placeholder: TweeterView.theme.photoImage
            };
        }

        visible = true;
    }
}

// Trim the string if length is greater than specified length
public function trimString(string:String, length:Integer) : String {

    if(string == null) return "";

    if(string.length() > length) {
        return "{string.substring(0, length).trim()}...";
    } else {
        return string;
    }
}