FX

/* 
 * DO NOT ALTER OR REMOVE COPYRIGHT NOTICES OR THIS FILE HEADER
 * Copyright 2009 Sun Microsystems, Inc. All rights reserved. Use is subject to license terms. 
 * 
 * This file is available and licensed under the following license:
 * 
 * Redistribution and use in source and binary forms, with or without 
 * modification, are permitted provided that the following conditions are met:
 *
 *   * Redistributions of source code must retain the above copyright notice, 
 *     this list of conditions and the following disclaimer.
 *
 *   * Redistributions in binary form must reproduce the above copyright notice,
 *     this list of conditions and the following disclaimer in the documentation
 *     and/or other materials provided with the distribution.
 *
 *   * Neither the name of Sun Microsystems nor the names of its contributors 
 *     may be used to endorse or promote products derived from this software 
 *     without specific prior written permission.
 * 
 * THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS "AS IS" AND
 * ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED
 * WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE ARE
 * DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT OWNER OR CONTRIBUTORS BE LIABLE FOR
 * ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES
 * (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES;
 * LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON
 * ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
 * (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF THIS
 * SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
 */
package rssviewer.parser;

import java.io.InputStream;
import javafx.data.pull.Event;
import javafx.data.pull.PullParser;
import javafx.data.xml.QName;
import rssviewer.model.Channel;
import rssviewer.model.Item;

public class RSSPullParser {
    
    public function parse(input: InputStream): Channel[] {
        
        // Information about all channels
        var channel: Channel[];
        var tmpChannel = null;
        var tmpItem = null;
        var itemTag = false;
        
        // Parse the input data (Channel Metadata) and construct Channel instance
        def parser = PullParser { 
                
            input: input 
                    
            onEvent: function(event: Event) {

                if (event.type == PullParser.START_ELEMENT) {
                    if(event.qname.name == "channel" and event.level == 1) {
                        tmpChannel = Channel{};
                    } else if(event.qname.name == "item" and event.level == 2) {
                        tmpItem = Item{};
                        itemTag = true;
                    }
                } else if(event.type == PullParser.END_ELEMENT) {
                    if(event.qname.name == "channel" and event.level == 1) {
                        if(tmpChannel != null) {
                            insert tmpChannel into channel;
                            tmpChannel = null;
                        }
                    } else if(event.qname.name == "item" and event.level == 2) {
                        if(tmpItem != null) {
                            insert tmpItem into tmpChannel.item;
                            tmpItem = null;
                            itemTag = false;
                        }
                    }
                } else if (event.type == PullParser.TEXT) {
                    if(event.text.trim().length() > 0) { 
                         // Channel
                        if(event.qname.name == "title" and event.level == 2) {
                            tmpChannel.title = event.text;
                        } else if(event.qname.name == "link" and event.level == 2) {
                            tmpChannel.link = event.text;
                        } else if(event.qname.name == "language" and event.level == 2) {
                            tmpChannel.language = event.text;
                        } else if(event.qname.name == "webMaster" and event.level == 2) {
                            tmpChannel.webMaster = event.text;
                        } else if(event.qname.name == "copyright" and event.level == 2) {
                            tmpChannel.copyright = event.text;
                        } else if(event.qname.name == "pubDate" and event.level == 2) {
                            tmpChannel.pubDate = event.text;
                        } else if(event.qname.name == "lastBuildDate" and event.level == 2) {
                            tmpChannel.lastBuildDate = event.text;
                        } else if(itemTag) {  // Item
                            if(event.qname.name == "title" and event.level == 3) {
                                tmpItem.title = event.text;
                            } else if(event.qname.name == "link" and event.level == 3) {
                                tmpItem.link = event.text;
                            } else if(event.qname.name == "pubDate" and event.level == 3) {
                                tmpItem.pubDate = event.text;
                            } else if(event.qname.name == "description" and event.level == 3) {
                                tmpItem.description = event.text;
                            }
                        } else { // Image
                            if(event.qname.name == "title" and event.level == 3) {
                                tmpChannel.imageTitle = event.text;
                            } else if(event.qname.name == "url" and event.level == 3) {
                                tmpChannel.imageURL = event.text;
                            } else if(event.qname.name == "link" and event.level == 3) {
                                tmpChannel.imageLink = event.text;
                            }
                        }
                    }
                } else if (event.type == PullParser.CDATA) {
                    if(event.text.trim().length() > 0) {
                        if(itemTag) {  // Item
                            if(event.qname.name == "description" and event.level == 3) {
                                tmpItem.description = event.text;
                            }
                        }
                    }
                }
            }
        }
        parser.parse();
        
        return channel;
    }
}