License text 

/*
 * DO NOT ALTER OR REMOVE COPYRIGHT NOTICES OR THIS FILE HEADER 
 * Copyright  2008, 2010 Oracle and/or its affiliates.  All rights reserved. 
 * Use is subject to license terms.
 * 
 * This file is available and licensed under the following license:
 * 
 * Redistribution and use in source and binary forms, with or without 
 * modification, are permitted provided that the following conditions are met: 
 * 
 *   * Redistributions of source code must retain the above copyright notice, 
 *     this list of conditions and the following disclaimer. 
 *
 *   * Redistributions in binary form must reproduce the above copyright notice,
 *     this list of conditions and the following disclaimer in the documentation
 *     and/or other materials provided with the distribution.
 *
 *   * Neither the name of Oracle Corporation nor the names of its contributors 
 *     may be used to endorse or promote products derived from this software 
 *     without specific prior written permission. 
 *
 * THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS 
 * "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT 
 * LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR 
 * A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT 
 * OWNER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL, 
 * SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED TO, 
 * PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR PROFITS; 
 * OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, 
 * WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR 
 * OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF 
 * ADVISED OF THE POSSIBILITY OF SUCH DAMAGE. 
 */

    

/*
 * ContactNode.fx
 *
 * Created on Apr 21, 2009, 9:03:25 PM
 */

package fxaddressbook;

import javafx.scene.Node;
import javafx.scene.Group;
import javafx.scene.Cursor;
import javafx.geometry.HPos;
import javafx.scene.text.Text;
import javafx.scene.text.Font;
import javafx.scene.CustomNode;
import javafx.scene.image.Image;
import javafx.scene.paint.Color;
import javafx.scene.layout.VBox;
import javafx.scene.layout.Stack;
import javafx.scene.image.ImageView;
import javafx.scene.shape.Rectangle;
import javafx.scene.input.MouseEvent;

import fxaddressbook.Main;
import fxaddressbook.Details.*;
import fxaddressbook.LocationY;

//@author JavaFX Samples Team

public var loc:LocationY;

// Contact List class
public class ContactNode extends CustomNode {
    public var name:String;
    public var phone:String;
    public var email:String;
    public var location:String;
    public var imageurl:String;
    public var visibility:Boolean = false;

    var details: Group = Group {
        visible: bind visibility
        layoutX: 5
        layoutY: 35
        content: [
            VBox {
                hpos: HPos.LEFT
                content: [
                    Text {
                        fill: Color.WHITE
                        font:Font { size: 10 }
                        content: bind "Mobile No.: {phone}"
                        cursor: Cursor.HAND
                        onMouseClicked:function(e:MouseEvent):Void {
                            Main.dialInterface.visible = true;
                            Main.dialInterface.phoneNumber = phone;
                            Main.dialInterface.startDialing();
                        }
                    },
                    Text {
                        fill: Color.WHITE
                        font:Font { size: 10 }
                        content: bind "Email: {email}"
                        cursor: Cursor.HAND
                        onMouseClicked:function(e:MouseEvent):Void {
                            Main.emailInterface.visible = true;
                            println("STAGE_WIDTH {STAGE_WIDTH} ... STAGE_HEIGHT {STAGE_HEIGHT}");
                        }
                    }
                    Text {
                        fill: Color.WHITE
                        font:Font { size: 10 }
                        content: bind "Location: {location}"
                        cursor: Cursor.HAND
                        onMouseClicked:function(e:MouseEvent):Void {
                            Main.app_title = "Loading ...";
                            Main.app_title1 = "";
                            Main.visible = true;
                            Main.mapDisplayed = true;
                            Main.mainDisplayed = false;
                            loc = LocationY { zip: location };
                        }
                    },
                ]
            }
            ImageView {
                layoutX: STAGE_WIDTH-100
                image: bind Image {
                    height: 55
                    width: 60
                    url: "{__DIR__}images/{imageurl}"
                }
            }
        ]
    }
    var contactBar = Group {
        content: [
            Rectangle {
                width: STAGE_WIDTH -21
                height: 30
                fill: Color.TRANSPARENT
                stroke: Color.LIGHTGRAY
            },
            Text {
                layoutX: 15
                layoutY: 18
                fill: Color.WHITE
                font:Font {
                    size: 13
                }
                content: name
            },
            Stack {
                layoutX: STAGE_WIDTH-55
                layoutY: 6
                content: [
                    Rectangle {
                        width: 15
                        height: 15
                        arcHeight: 5
                        arcWidth: 5
                        fill: Color.TRANSPARENT
                        stroke: Color.GRAY
                        strokeWidth: 2
                        onMouseClicked: function(e: MouseEvent): Void {
                            visibility = not visibility;
                        }
                    },
                    Text {
                        fill: Color.WHITE
                        content: bind if(visibility) "-" else "+";
                    }
                ]
            }
        ]
    }


    public override function create():Node {
        return Group {
            content: [
                details,
                contactBar,
            ]
        };
    }
}