License text 

/*
 * DO NOT ALTER OR REMOVE COPYRIGHT NOTICES OR THIS FILE HEADER 
 * Copyright  2008, 2010 Oracle and/or its affiliates.  All rights reserved. 
 * Use is subject to license terms.
 * 
 * This file is available and licensed under the following license:
 * 
 * Redistribution and use in source and binary forms, with or without 
 * modification, are permitted provided that the following conditions are met: 
 * 
 *   * Redistributions of source code must retain the above copyright notice, 
 *     this list of conditions and the following disclaimer. 
 *
 *   * Redistributions in binary form must reproduce the above copyright notice,
 *     this list of conditions and the following disclaimer in the documentation
 *     and/or other materials provided with the distribution.
 *
 *   * Neither the name of Oracle Corporation nor the names of its contributors 
 *     may be used to endorse or promote products derived from this software 
 *     without specific prior written permission. 
 *
 * THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS 
 * "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT 
 * LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR 
 * A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT 
 * OWNER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL, 
 * SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED TO, 
 * PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR PROFITS; 
 * OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, 
 * WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR 
 * OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF 
 * ADVISED OF THE POSSIBILITY OF SUCH DAMAGE. 
 */

    

package brickbreaker;

import javafx.scene.*;
import javafx.scene.image.*;
import javafx.geometry.Rectangle2D;

/**
 * @author Pavel Porvatov
 */

// Default size of the bat
public def DEFAULT_SIZE = if(Config.screenHeight > 500 and __PROFILE__ == "mobile") 1 else 2;

// Maximum size of the bat
public def MAX_SIZE = 7;

public class Bat extends CustomNode {
    // Size of the bat
    public var size = DEFAULT_SIZE;

    // Width of the bat (without shadow)
    public-read var width: Integer = bind (size * 12 + 45) * Config.scale as Integer;

    // Height of the bat (without shadow)
    public-read var height;

    override public function create(): Node {
        // Create bat from three parts: left, central and right
        var left = Config.images[Config.IMAGE_BAT_LEFT];
        var center = Config.images[Config.IMAGE_BAT_CENTER];
        var right = Config.images[Config.IMAGE_BAT_RIGHT];
        var rightWidth = right.width - Config.shadowWidth;

        height = center.height - Config.shadowHeight;

        Group {
            content: [
                // The left part of the bat
                ImageView {
                    image: left
                },

                // The central part of the bat
                ImageView {
                    image: center
                    translateX: left.width
                    viewport: bind Rectangle2D {
                        var centerWidth = width - left.width - rightWidth;

                        minX: (center.width - centerWidth) / 2
                        width: centerWidth
                        height: center.height
                    }
                },

                // The right part of the bat
                ImageView {
                    image: right
                    translateX: bind width - rightWidth;
                }
            ]
        }
    }
}